Section 3.12　例外処理（その１）

buffer.open("alarm.wav");

buffer.open("startup.tjs");

// FileSelector.tjs から FileSelector クラスの定義を読み込みます
Scripts.execStorage("FileSelector.tjs");

class SoundWindow2 extends Window
{
    var selector;  // FileSelector クラスのオブジェクト
    var buffer;    // WaveSoundBuffer クラスのオブジェクト

    // コンストラクタ
    function SoundWindow2()
    {
        super.Window();  // スーパークラスのコンストラクタを呼び出します

        // FileSelector クラスのオブジェクトを作ってウィンドウに管理してもらいます
        selector = new FileSelector();
        add(selector);

        // WaveSoundBuffer クラスのオブジェクトを作ってウィンドウに管理してもらいます
        buffer = new WaveSoundBuffer(this);
        add(buffer);
        buffer.looping = true;  // ループ再生します

        caption = "ファイルが開かれていません";  // ウィンドウのタイトルバーの文字列を設定します
        visible = true;
    }

    // デストラクタ
    function finalize()
    {
        super.finalize();  // スーパークラスのデストラクタを呼び出します
    }

    // サウンドファイルを開くメソッド
    function open()
    {
        try
        {
            // このブロック内で発生した例外が捕捉されます
            if(selector.openFile())
            {
                // ファイルが選択された場合はそのファイルを開きます
                buffer.open(selector.name);
                // 開かれたファイル名をウィンドウのタイトルバーに表示します
                caption = Storages.extractStorageName(selector.name) + " が開かれています";
            }
        }
        catch(e)
        {
            // try ブロック内で例外が起きるとこのブロック内のスクリプトが実行されます
            System.inform(e.message);  // 例外の内容を表示します
            caption = "ファイルが開かれていません";
        }
    }

    // サウンドを再生するメソッド
    function play()
    {
        if(buffer.status == "stop")
            buffer.play();  // 現在停止中であれば再生を開始します
    }

    // サウンドの再生を停止するメソッド
    function stop()
    {
        if(buffer.status == "play")
            buffer.stop();  // 現在再生中であれば再生を停止します
    }

    // action メソッド
    function action(ev)
    {
        // ウィンドウに対する onKeyDown イベントを処理します
        if(ev.target == this && ev.type == "onKeyDown")
        {
            if(ev.key == VK_O)
                open();  // O キー → ファイルを開く
            else if(ev.key == VK_P)
                play();  // P キー → 再生
            else if(ev.key == VK_S)
                stop();  // S キー → 停止
        }
    }
}

// ogg 形式のファイルを再生する場合は、krkr.eXe のあるフォルダに wuvorbis.dll をコピーしてから
// 下の行のコメントを外してください
// Plugins.link("wuvorbis.dll");

var win = new SoundWindow2();  // ウィンドウを作ります