Section 4.3　レイヤを使ったプラグイン

; KAG スクリプトとして読み込めるようにします
[iscript]

class LayerPlugin extends KAGPlugin
{
    var foreLay;  // 表画面用のレイヤ
    var backLay;  // 裏画面用のレイヤ

    // コンストラクタ
    function LayerPlugin()
    {
        super.KAGPlugin();  // スーパークラスのコンストラクタを呼び出します

        // 表画面用のレイヤを作ります
        foreLay = new Layer(kag, kag.fore.base);  // 表画面の背景レイヤを親レイヤにします
        with(foreLay)
        {
            .setSize(128, 128);  // サイズを 128×128 ピクセルにします
            .setPos(64, 64);  // 位置を (64, 64) に設定します
            .fillRect(0, 0, .width, .height, 0xFFFF0000);  // レイヤ内を赤色で塗りつぶします
            .visible = true;  // 表示状態にします
        }

        // 裏画面用のレイヤを作ります
        backLay = new Layer(kag, kag.back.base);  // 裏画面の背景レイヤを親レイヤにします
        with(backLay)
        {
            .setSize(128, 128);  // サイズを 128×128 ピクセルにします
            .setPos(64, 64);  // 位置を (64, 64) に設定します
            .fillRect(0, 0, .width, .height, 0xFF0000FF);  // レイヤ内を青色で塗りつぶします
            .visible = true;  // 表示状態にします
        }
    }

    // デストラクタ
    function finalize()
    {
        invalidate foreLay;  // 表画面用のレイヤを無効化します
        invalidate backLay;  // 裏画面用のレイヤを無効化します

        super.finalize();  // スーパークラスのデストラクタを呼び出します
    }
}

// プラグインオブジェクトを作って kag オブジェクトに登録します
kag.addPlugin(new LayerPlugin());

[endscript]

; call タグで読み込めるように、最後に return タグを書きます
[return]